* The original content of this file may be under copyright from 
* ON Semiconductor and/or Intusoft as far as I know.
* The modifications of this model have been only done for a scientific 
* investigation. Don't distribute or commercially use this modified model.

********
*SRC=UC1843;UC1843;PWM Models;Unitrode;Full Transient
*SYM=1845
.SUBCKT UC1843  3     14   15   1     18    4   20   2  
*              E/A   FDBK  IS  RT/CT  GND  OUT  VC  VREF
****OSCILLATOR*****
S1 8 18 1 18 SOSC
.MODEL SOSC SW(RON=.01 ROFF=1MEG VT=1.9 VH=.85)
*@BDISCH 1 18 I=V(8,18) < 2.5 ? V(13,18) > 2.5 ? 10M : 0
BDISCH 1 18 I=IF((V(8,18) < 2.5), IF((V(13,18) > 2.5),10M, 0), 0)
RPULL 8 2 100K
****UVLO***********
S4 20 19 20 18 SUVLO
.MODEL SUVLO SW(RON=.01 ROFF=1MEG VT=8 VH=.4)
RUVLO 19 18 1MEG
RSTDBY 20 18 16.8K
ROP 10 18 500
****REFERENCE*******
*@BREF 13 18 V=V(19,18) > 6 ? 5 : 0
BREF 13 18 V=IF(V(19,18) > 6, 5 , 0)
RREG 10 2 .33
CREF 2 18 1n
V3 13 10 0
B6 19 18 I=I(V3)
****CURRENT COMPARATOR*******
*@B3 21 18 V=V(15,18) > V(16,18) ? 5 : 0
B3 21 18 V=IF(V(15,18) > V(16,18), 5 , 0)
R7 15 18 1MEG
RDELAY 21 22 1K
CDELAY 22 18 150P
****ERROR AMPLIFIER**********
XAMP 2 14 3 18 1845AMP
****OFFSET LIMITER***********
R4 12 11 2MEG
R6 11 18 1MEG
*@B2 16 18 V=V(11,18) > 1 ? 1 : V(11,18)
B2 16 18 V=IF(V(11,18) > 1 , 1 , V(11,18))
V4 3 9 1
D1 9 12 D2
.MODEL D2 D 
****OUTPUT DRIVER************
XDRIVE 19 18 5 4 1845OUT

****S-R LATCH****************
*XLATCH 8 2 22 18 6 7 FFLOP
*
****S-R LATCH****************
*@XLATCH 8 2 22 18 6 7 FFLOP
A1 2 0 8 18 22 6 7 0 dflop  ref=1.5 vhigh=3.5 vlow=0.3 td=10n
*Syntax: A1   d 0 clk pre clr q_ q 0 DFLOP

****OUTPUT AND GATE**********
*@B8 5 18 V=V(2,18) > 2.5 ? V(7,18) > 2.5 ? V(8,18) > 2.5 ? 10 : 0
*B8 5 18 V=IF((V(2,18) > 2.5), IF((V(7,18) > 2.5), IF((V(8,18) > 2.5), 10,0), 0), 0)
B8 5 18 V=IF( (V(2,18) > 2.5)&((V(7,18) > 2.5)&(V(8,18) > 2.5)), 10, 0 )
.ENDS

*include pwmic.lib
*********
*SYM=1845AMP
.SUBCKT 1845AMP  4     1    9   20
*                VREF  INV  OUT V-
.MODEL QPMOD PNP
.MODEL DCLAMP D (RS=10 BV=5 IBV=.01)
.MODEL DMOD D
R1 10 4 100K
R2 10 20 100K
R3 6 20 316MEG
C1 6 20 15.9P
E1 5 20 6 20 1
R4 1 20 8MEG
I2 4 9 .8M
D12 9 4 DMOD
R6 20 3 300
D11 9 12 DMOD
Q1 20 13 12 QPMOD
I3 13 20 68U
D14 3 13 DMOD
D15 20 6 DCLAMP
L1 2 3 10U
C2 3 20 200P
R9 5 2 5
C5 2 20 .02U
G1 20 6 10 1 100U
.ENDS
*********
*SYM=OUT
.SUBCKT 1845OUT  4  7  3  12
*                +V -V IN OUT
.MODEL QMOD NPN RC=1.5  RE=.5 RB=100  IKF=0.5
.MODEL QMOD2 NPN
.MODEL QIN NPN BF=100 BR=2 IS=1E-16 VAF=50 
+ CJE=1.5P CJC=.15P TR=1N TF=4N
.MODEL DMOD D RS=1 IS=0.4U
I3 4 8 100U
D3 8 4 DMOD
D4 12 8 DMOD
Q3 8 1 9 QIN
Q4 12 9 7 QMOD
Q5 4 8 6 QMOD
I4 7 1 .9M
R1 3 2 10K
Q8 1 2 7 QIN
Q2 4 6 12 QMOD2
.ENDS
******************