***************************************************************
* Infineon Technologies AG
* GUMMEL-POON Transistor MODEL IN SPICE 2G6 SYNTAX
* BFR360L3 IN P-TSLP-3-1
* preliminary Data! 
* Incuding 1/f Noise model
* March 2002
***************************************************************
.SUBCKT BFR360L3 10 20 30
LB 1 10 0.575E-9
LC 2 20 0.275E-9
LE 3 30 0.575E-9
CCBo 10 20 8E-15
CCEo 20 30 8E-15
CBEo 30 10 24E-15
CCBi 1 2 33E-15
CCEi 2 3 131E-15
CBEi 3 1 28E-15
CS 2 200 300E-15
RS 200 20 204
Q1 2 1 3 BFR360_Chip
.ENDS
***************************************************************
* Transistor chip:
.MODEL BFR360_Chip NPN(
+ IS = 68.92e-18   BF = 147          NF = 1.0
+ VAF = 20         IKF = 77.28e-3    ISE = 150e-15
+ NE = 2.4         BR = 6.0          NR = 1
+ VAR = 60         IKR = 0.3         ISC = 20e-15
+ NC = 1.4         RB = 0.100        IRB = 74e-6
+ RBM = 7.31       RE = 78.2e-3      RC = 0.35
+ CJE = 400e-15    VJE = 1.3         MJE = 0.5
+ TF = 9.21915e-12 XTF = 0.114836    VTF = 0.19762
+ ITF = 0.0013364  PTF = 0           CJC = 473e-15
+ VJC = 0.864      MJC = 0.48639     XCJC = 0.129
+ TR = 1.91975e-09 CJS= 0            VJS = 0.75
+ MJS = 0          XTB = 0           EG = 1.11
+ XTI = 0          FC = 0.954447     NK = 0.5
+ Kf = 1e-14       Af = 1)
***************************************************************
